@echo off
setlocal

set "API_BASE=http://127.0.0.1:51077/api/v1/settings"
set "CONFIG_DIR=C:\ProgramData\ESP\ESM\um"
set "GISMT_ADDRESS=https://ts-reg.crpt.ru:19100"
set "CDN_CODES_CHECK_TIMEOUT=4000"
set "CDN_HEALTH_CHECK_TIMEOUT=3000"
set "ALLOW_REMOTE_CONNECTION=true"

for %%F in ("%CONFIG_DIR%\config_*.yml") do (
  set "KKT_FILE=%%~nxF"
  goto :kkt_found
)

:kkt_not_found
echo Не найден файл вида config_*.yml в %CONFIG_DIR%.
exit /b 1

:kkt_found
call set "KKT_SERIAL=%%KKT_FILE:config_=%%"
call set "KKT_SERIAL=%%KKT_SERIAL:.yml=%%"

if "%KKT_SERIAL%"=="" (
  echo Не удалось определить заводской номер ККТ из имени файла %KKT_FILE%.
  exit /b 1
)

echo Найден номер ККТ: %KKT_SERIAL%
echo Отправка настроек для ККТ %KKT_SERIAL%...

curl -X PUT "%API_BASE%/%KKT_SERIAL%" ^
  -H "Content-Type: application/json" ^
  --data-raw "{\"allowRemoteConnection\":%ALLOW_REMOTE_CONNECTION%,\"gismtAddress\":\"%GISMT_ADDRESS%\",\"cdnCodesCheckTimeout\":%CDN_CODES_CHECK_TIMEOUT%,\"cdnHealthCheckTimeout\":%CDN_HEALTH_CHECK_TIMEOUT%}"

if errorlevel 1 (
  echo Не удалось обновить настройки.
  exit /b 1
)

echo Готово.
exit /b 0